边缘检测

在后期处理中，如果要使画面中的轮廓更深一些，或者一些其他和轮廓相关的处理，我们需要首先找出代表轮廓的像素，这就需要进行边缘检测

1.边缘是如何形成的？

如果相邻像素之间存在差别的差别(如:颜色、亮度)，那它们之间就会形成一条边界，这个边界就是图像的轮廓，我们可以用变量gradient(梯度)，来表示像素之间的差异，那么gradient越大越有可能是边缘(当然如果可以保证gradient最大不会超过1，那么我们可以认为1-gradient，越小越有可能是边界)，那么边缘检测其实就是求gradient的一个过程

2.如何求gradient(梯度)？

求gradient需要利用一些边缘检测算子对图像进行卷积操作实现的

卷积操作(运算)

简单理解就是每一个像素都和它周围的N个像素颜色分别乘以对应的权重值，然后再求和得到新的颜色值的过程就叫做卷积操作

卷积核

就是卷积操作中的 计算范围

通常情况下，卷积核是一个nxn的四方形网格结构(如: 2x2 3x3)，并且把当前像素放到卷积核的中心

检测算子

卷积核中每个位置的权重的不同配置即不同的检测算子，常用的检测算子

(两个卷积核，一个代表水平方向，一个代表竖直方向)

介绍完前置知识点我们来具体阐述gradient的求法

1.分别计算水平与竖直两个方向的卷积值(Gx,与Gy)

2.设梯度值为G,则\(G=\left | G_{x} \right |+\left | G_{y} \right |\)

此处贴出Shader代码如下(使用sobel检测算子)：

Shader "Custom/EdgeCheck_Sobel" {
	Properties {
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_EdgeOnly ("Edge Only", Float) = 1.0
		_EdgeColor ("Edge Color", Color) = (0, 0, 0, 1)
		_BackgroundColor ("Background Color", Color) = (1, 1, 1, 1)
	}
	SubShader {
		Pass 
		{  
			ZTest Always 
			Cull Off
			ZWrite Off
			CGPROGRAM
			#include "UnityCG.cginc"
			#pragma vertex vert  
			#pragma fragment fragSobel
			
			sampler2D _MainTex;  
		    //_MainTex纹理中单位纹素的大小(例:512X515图纹理,_MainTex_TexelSize.x=_MainTex_TexelSize.y=1/512)
			uniform half4 _MainTex_TexelSize;
			//只显示边缘 0:边缘加深  1:只显示边缘
			fixed _EdgeOnly;
			//边缘颜色
			fixed4 _EdgeColor;
			//背景颜色
			fixed4 _BackgroundColor;
			
			struct v2f 
			{
				float4 pos : SV_POSITION;
				half2 uv[9] : TEXCOORD0;
			};
			  
			v2f vert(appdata_img v) 
			{
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				half2 uv = v.texcoord;
				//求卷积核中每个位置的纹理坐标(uv坐标系原点在左下角)
				o.uv[0] = uv + _MainTex_TexelSize.xy * half2(-1, 1); //左上
				o.uv[1] = uv + _MainTex_TexelSize.xy * half2(0, 1);  //中上
				o.uv[2] = uv + _MainTex_TexelSize.xy * half2(1, 1);  //右上

				o.uv[3] = uv + _MainTex_TexelSize.xy * half2(-1, 0); //左中
				o.uv[4] = uv + _MainTex_TexelSize.xy * half2(0, 0);  //中中
				o.uv[5] = uv + _MainTex_TexelSize.xy * half2(1, 0);  //右中

				o.uv[6] = uv + _MainTex_TexelSize.xy * half2(-1, -1); //左下
				o.uv[7] = uv + _MainTex_TexelSize.xy * half2(0, -1);  //中下
				o.uv[8] = uv + _MainTex_TexelSize.xy * half2(1, -1);  //右下
				return o;
			}
			
			//亮度值
			fixed luminance(fixed4 color)
			{
				return  0.2125 * color.r + 0.7154 * color.g + 0.0721 * color.b; 
			}
			
			half Sobel(v2f i) 
			{
				const half Gx[9] = { -1, -2, -1,
									0,  0,  0,
									1,  2,  1 };

				const half Gy[9] = {-1,  0,  1,
									-2,  0,  2,
									-1,  0,  1};

				half texColor;
				half edgeX = 0;
				half edgeY = 0;
				for (int it = 0; it < 9; it++) 
				{
					texColor = luminance(tex2D(_MainTex, i.uv[it]));
					edgeX += texColor * Gx[it];
					edgeY += texColor * Gy[it];
				}
				
				half edge = 1 - abs(edgeX) - abs(edgeY);
				return edge;
			}
			
			fixed4 fragSobel(v2f i) : SV_Target 
			{
				half edge = Sobel(i);
				fixed4 withEdgeColor = lerp(_EdgeColor, tex2D(_MainTex, i.uv[4]), edge);
				fixed4 onlyEdgeColor = lerp(_EdgeColor, _BackgroundColor, edge);
				return lerp(withEdgeColor, onlyEdgeColor, _EdgeOnly);
 			}
			
			ENDCG
		} 
	}
	FallBack Off
}

其他检测算子代码雷同就不贴了

效果图如下:(从左往右依次为原图->Roberts检测算子->Prewitt检测算子->Sobel检测算子)

项目下载地址:https://pan.baidu.com/s/1xkxSb9DmceIdEAhcDXg5ZA 提取码: w4ne

文章评论